lucas.lopes.paula

Qui Abr 02, 2020 6:26 pm
Stimulus Machine #DesafioRoboCore - Código Fonte

STIMULUS MACHINE: veja o quão rápido você é!

 


Código:#define resposta 2  //botão resposta
#define jogar 3     //botão jogar
#define reset 4     //botão reset
#define mudaEstimulo 5  //botão mudar estímulo
#define ledRed 10   //Vermelho do RGB
#define ledGreen 9  //Verde do RGB
#define ledBlue 6   //Azul do RGB
#define buzzer 11   //saída do buzzer
#define rgb 1       //constante para controle da lógica

/*Variáveis necessárias para o controle da lógica*/
unsigned long tempoResposta, tempo;
int estimulo, iniciar, reiniciar, erro, ok, r, g, b;

/*Esta é a função que reinicia o jogo*/
void restart() {
  Serial.end();
  Serial.begin(9600);
  Serial.println("          STIMULUS MACHINE          ");
  Serial.println();
  Serial.println("Instruções:");
  Serial.println("  -> Aperte o botão JOGAR");
  Serial.println("  -> Aguarde o sinal de estímulo");
  Serial.println("  -> Aperte o botão RESPOSTA");
  Serial.println("  -> Aperte o botão MUDAR ESTÍMULO para alternar entre sonoro e visual");
  Serial.println();
  Serial.println();
  Serial.println("Obs.: É interessante notar que os seres humanos reagem mais rapdiamente");
  Serial.println("a estímulos sonoros do que a estímulos visuais.");
  Serial.println();
  Serial.println();
  Serial.println("Estímulo visual");
  estimulo = rgb;
  iniciar = reiniciar = HIGH;
  noTone(buzzer);
  analogWrite(ledRed, 255);
  analogWrite(ledGreen, 0);
  analogWrite(ledBlue, 0);
  delay(200);
  analogWrite(ledRed, 0);
  analogWrite(ledGreen, 255);
  analogWrite(ledBlue, 0);
  delay(200);
  analogWrite(ledRed, 0);
  analogWrite(ledGreen, 0);
  analogWrite(ledBlue, 255);
  delay(200);
  analogWrite(ledRed, 0);
  analogWrite(ledGreen, 0);
  analogWrite(ledBlue, 0);
}

void setup() {
  randomSeed(analogRead(A5)); //deixar o pino A5 desconectado para obter ruido
  //Todos os botões foram definidos como entradas PULL-UP (os níveis lógicos ficam invertidos)
  pinMode(resposta, INPUT_PULLUP);
  pinMode(jogar, INPUT_PULLUP);
  pinMode(reset, INPUT_PULLUP);
  pinMode(mudaEstimulo, INPUT_PULLUP);
  pinMode(ledRed, OUTPUT);
  pinMode(ledGreen, OUTPUT);
  pinMode(ledBlue, OUTPUT);
  digitalWrite(ledRed, LOW);
  digitalWrite(ledGreen, LOW);
  digitalWrite(ledBlue, LOW);
  pinMode(buzzer, OUTPUT);
  estimulo = rgb;
  iniciar = reiniciar = HIGH;
  noTone(buzzer);
  restart();
}

void loop() {
  iniciar = digitalRead(jogar);
  if (iniciar == LOW) {
    ok = 1;
    tempo = millis();
    erro = digitalRead(resposta);
    
    while((millis() - tempo) < 3000) {
      erro = digitalRead(resposta);
      reiniciar = digitalRead(reset);
      if (erro == LOW)
        break;
      else if (reiniciar == LOW) {
        ok = 0;
        restart();
        break;
      }
    }
    
    if (erro == HIGH && ok == 1) {
      if (estimulo == rgb) {
        r = random(0, 255);
        g = random(0, 255);
        b = random(0, 255);
        analogWrite(ledRed, r);
        analogWrite(ledGreen, g);
        analogWrite(ledBlue, b);
        noTone(buzzer);
        digitalWrite(buzzer, LOW);
      }
      else
        tone(buzzer, 3000);
      
      tempo = millis();  
      
      while(digitalRead(resposta)) {}
      
      tempoResposta = millis();
      digitalWrite(ledRed, LOW);
      digitalWrite(ledGreen, LOW);
      digitalWrite(ledBlue, LOW);
      noTone(buzzer);
      Serial.print("    Tempo de reação: ");
      Serial.print(tempoResposta - tempo);
      Serial.println(" ms");
    }
    else if (erro == LOW) {
      Serial.println("ERRO! (Não aguardou o estímulo)");
      Serial.println();
      tone(buzzer, 130);
      delay(200);
      noTone(buzzer);
    }
    iniciar = reiniciar = HIGH;
    
  }
  else if (!digitalRead(mudaEstimulo)) {
    Serial.println();
    Serial.println();
    Serial.print("Estímulo ");
    if (estimulo == rgb) {
      estimulo = buzzer;
      Serial.println("sonoro");
    }
    else {
      estimulo = rgb;
      Serial.println("visual");
    }
    delay(250);
  }
  else if (!digitalRead(reset))
    restart();
}[/img][/code]

hinhargos22

Ter Set 29, 2020 5:20 pm
Stimulus Machine #DesafioRoboCore - Código Fonte

Disponibiliza o link do tinkercad, ai para nois