Projeto Sensor de Ruído

This tutorial is not available in English

Projeto Sensor de Ruído

O Projeto Sensor de Ruído foi pensado como uma atividade educacional e maker, ideal para escolas, oficinas e ambientes de aprendizagem. A proposta é montar um semáforo do barulho, capaz de indicar visualmente o nível de ruído do ambiente.

Utilizando um sensor de som (microfone) e um Arduino, o projeto classifica o ruído em três níveis: pouco, médio e alto, representados respectivamente pelos LEDs verde, amarelo e vermelho.

O foco do projeto não é apenas o resultado final, mas o processo de observação, leitura de dados e interpretação dos valores mostrados no Serial Monitor.

Visão geral do projeto

O sistema funciona como um semáforo. A cada ciclo de leitura, apenas um LED permanece aceso: verde para pouco ruído, amarelo para ruído médio e vermelho para ruído alto.

Para evitar oscilações rápidas, o Arduino não utiliza uma leitura única. Ele realiza uma média de várias leituras, tornando o comportamento mais estável e fácil de interpretar em sala de aula.

Uma ideia de como ficaria o projeto montado — Através do Fritzing, fiz a construção de como seriam as conexões, considerando que os LEDs ali representam o nosso painel de farol de LEDs, que já possui resistores embutidos

Como o projeto decide a cor

O Arduino realiza o seguinte processo:

São feitas 5 leituras do sensor
Cada leitura observa um intervalo de 20 ms
A média dessas 5 leituras define o estado final

Regra utilizada (pela média do ruído, medida em pico a pico):
0 a 400: VERDE (pouco ruído)
401 a 600: AMARELO (ruído médio)
≥ 601: VERMELHO (ruído alto)

Lista de materiais

A lista de materiais foi pensada para facilitar o uso em escolas e oficinas. São componentes simples, fáceis de encontrar e adequados para atividades educacionais.

1x Arduino BlackBoard (ou Arduino UNO)
1x Sensor de som (microfone)
1x Módulo semáforo de LEDs (verde, amarelo e vermelho)
1x conjunto de jumpers macho-fêmea
1x cabo USB A/B

Conceito rápido (didático)

O microfone gera um sinal elétrico que oscila para cima e para baixo. Em vez de observar um valor fixo, medimos o quanto esse sinal varia ao longo do tempo (pico a pico).

Essa variação funciona como uma representação simplificada da intensidade do som, suficiente para atividades educacionais e discussões em grupo.

Ligações (LEDs verde, amarelo e vermelho)

Cada LED deve possuir um resistor em série para limitar a corrente. Isso evita danos tanto ao LED quanto ao Arduino.

Dica importante: o terminal maior do LED geralmente é o ânodo (+), enquanto o lado achatado do corpo indica o cátodo (-).

Código

O código foi desenvolvido para ser simples, estável e fácil de explicar. Ele serve como base para atividades educacionais e pode ser adaptado para diferentes contextos.

/************************************************************
 * Projeto: Teste de Ruído por Média (Serial + LEDs)
 *
 * Robocore
 * Autor: Alexandre Casemonstro   30/01/26
 *
 * Regra:
 * - Média 0 a 400   -> VERDE
 * - Média 401 a 600 -> AMARELO
 * - Média >= 601    -> VERMELHO

 * Funcionou bem, sem fade.
 ************************************************************/

const int PIN_MIC = A0;

// LEDs (ordem definida)
const int LED_VERDE    = 3;       //Pino de led Verde
const int LED_AMARELO  = 5;       //Pino do Led Amarelo
const int LED_VERMELHO = 6;       //Pino do led vermelho

/* =========================
   PARÂMETROS DE LEITURA
========================= */
const int NUM_LEITURAS = 5;
const int JANELA_MS   = 20;

/* =========================
   FUNÇÃO: leitura pico-a-pico
========================= */
int lerRuidoPicoAPico(int janelaMs)
{
  unsigned long inicio = millis();
  int minimo = 1023;
  int maximo = 0;

  while (millis() - inicio < janelaMs)
  {
    int leitura = analogRead(PIN_MIC);
    if (leitura < minimo) minimo = leitura;
    if (leitura > maximo) maximo = leitura;
  }

  return (maximo - minimo);
}

void setup()
{
  pinMode(LED_VERDE, OUTPUT);
  pinMode(LED_AMARELO, OUTPUT);
  pinMode(LED_VERMELHO, OUTPUT);

  // garante tudo apagado
  digitalWrite(LED_VERDE, LOW);
  digitalWrite(LED_AMARELO, LOW);
  digitalWrite(LED_VERMELHO, LOW);

  Serial.begin(115200);
  delay(300);

  Serial.println("====================================");
  Serial.println("Legenda:");
  Serial.println("VERDE    -> Media 0 a 400");
  Serial.println("AMARELO  -> Media 401 a 600");
  Serial.println("VERMELHO -> Media >= 601");
  Serial.println("====================================");
}

void loop()
{
  int somaRuido = 0;

  // Coleta das leituras
  for (int i = 0; i < NUM_LEITURAS; i++)
  {
    int p2p = lerRuidoPicoAPico(JANELA_MS);
    somaRuido += p2p;
  }

  // Calcula média
  int mediaRuido = somaRuido / NUM_LEITURAS;

  // Apaga todos os LEDs antes de decidir
  digitalWrite(LED_VERDE, LOW);
  digitalWrite(LED_AMARELO, LOW);
  digitalWrite(LED_VERMELHO, LOW);

  // Classificação baseada SOMENTE na média
  Serial.print("Media do Ruido (p2p): ");
  Serial.print(mediaRuido);
  Serial.print(" | Estado: ");

  if (mediaRuido <= 400)
  {
    Serial.println("VERDE (Pouco Ruido)");
    digitalWrite(LED_VERDE, HIGH);
  }
  else if (mediaRuido <= 600)
  {
    Serial.println("AMARELO (Ruido Medio)");
    digitalWrite(LED_AMARELO, HIGH);
  }
  else
  {
    Serial.println("VERMELHO (Ruido Alto)");
    digitalWrite(LED_VERMELHO, HIGH);
  }

  delay(200); // intervalo entre ciclos
}

Testes e calibração

Em silêncio, o LED tende a ficar verde.
Falando próximo ao sensor, o LED tende a amarelo.
Batendo palmas, o LED tende a vermelho.

Caso o ambiente seja muito barulhento ou muito silencioso, os valores de referência podem ser ajustados no código. Essa adaptação pode ser explorada como atividade em sala.

Boas práticas

A calibração, para ter um melhor efeito, precisa ser feita no local onde você quer utilizá-la, para ter a calibração exata
Utilizar sempre resistores em série com os LEDs.
Garantir GND comum entre o sensor e o Arduino.
Evitar cabos longos para o sensor de som.
Testar o circuito antes de levar para a sala de aula.
Incentivar a observação dos valores no Serial Monitor.