NodeMCU e o uso de APIs

Neste tutorial em video mostramos como utilizar uma API do Google no NodeMCU. Nele fazemos a leitura através da API do YouTube da quantidade de inscritos de um canal. Mostramos essa quantidade de inscritos em Módulos Display Serial.

Os principais itens usados nesse video são:

Lista completa de produtos

comprar

NodeMCU ESP8266-12 V2

R$49.00

Módulo Display Serial

R$29.90 x5

Fonte Chaveada 9V 1A

R$16.50

Adaptador P4 Fêmea - Borne

R$3.90

Mini Protoboard 170 Pontos - Preta

R$7.90

Jumper Premium 10 cm M/M - Pacote com 10 unidades

R$4.00

Jumper Premium 20 cm M/F - Pacote com 10 unidades

R$5.00

#include "SerialDisplay.h"
#include "ArduinoJson.h"
#include "ESP8266WiFi.h"
#include "WiFiClientSecure.h"
  
char ssid[] = "NOME-DA-SUA-REDE-WIFI-AQUI";       // sua rede wifi
char password[] = "SENHA-DA-SUA-REDE-WIFI-AQUI";  // sua senha
char channelId[] = "ID-DO-SEU-CANAL"; // ID do seu canal
char apiKey[] = "CHAVE-DA-API"; // chave da API
  
SerialDisplay displays(14, 12, 10); // (data D5, clock D6, qtde de modulos)
  
WiFiClientSecure client;
  
String mensagemAnterior = "";

void setup() {
  for (int x = 1; x < 11; x++) {
    displays.Print(1, x);
  }

  Serial.begin(9600);
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  delay(100);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  IPAddress ip = WiFi.localIP();
  Serial.println(ip);

  client.setInsecure(); // necessario para algumas versoes do ESP8266 para Arduino
}

void loop() {
  checarInscritos();
  delay(10000); // checa inscritos de 10 em 10 segundos
}

void checarInscritos() {
  client.flush();
  client.setTimeout(10000);
  if (!client.connect("www.googleapis.com", 443)) {  // 443: YouTube API SSL Port
    Serial.println("Nao consegui conexao a API");
    return;
  } else {
    Serial.println("Consegui conexao a API");
  }
  String chamarAPI = "GET https://www.googleapis.com/youtube/v3/channels?part=statistics&id=";
  chamarAPI += channelId;
  chamarAPI += "&key=";
  chamarAPI += apiKey;
  chamarAPI += " HTTP/1.1";
  client.println(chamarAPI);
  client.println(F("Connection: close"));
  if (client.println() == 0) {
    return;
  }
  char status[32] = {0};
  client.readBytesUntil('\r', status, sizeof(status));
  if (strcmp(status, "HTTP/1.1 200 OK") != 0) {
    return;
  }
  // Skip HTTP headers
  char endOfHeaders[] = "\r\n\r\n";
  if (!client.find(endOfHeaders)) {
    return;
  }
  String resposta = "";
  while (client.available()) {
    char c = client.read();
    resposta += c;
  }
  String resposta_final = resposta.substring(3);
  Serial.print("Resposta:");
  Serial.println(resposta_final);
  // Allocate JsonBuffer
  // Use arduinojson.org/assistant to compute the capacity.
  const size_t capacity = JSON_ARRAY_SIZE(1) + JSON_OBJECT_SIZE(1) + 2 * JSON_OBJECT_SIZE(4) + JSON_OBJECT_SIZE(5) + 300;
  DynamicJsonDocument doc(capacity);

  deserializeJson(doc, resposta_final);

  JsonObject items_0 = doc["items"][0];
  JsonObject items_0_statistics = items_0["statistics"];
  const char* numero_de_inscritos = items_0_statistics["subscriberCount"]; // "53200"
 
  String mensagem = numero_de_inscritos;
  Serial.print("Numero de inscritos: ");
  Serial.println(mensagem);
  
  if (mensagem != mensagemAnterior) {
    for (int cont = 0; cont <= 10 ; cont++) {
      if (mensagem.length() >= cont + 1) {
        displays.Print(mensagem[cont], cont + 1);
        delay(10);
      } else {
        displays.Off(cont + 1); // apaga displays que nao estiverem sendo usados
      }
    }
    mensagemAnterior = mensagem;
  }
  
  // Disconnect
  client.stop();
}

Deixe abaixo seus comentários e ideias para próximos tutoriais em video!

Você instalou a biblioteca <ArduinoJSON> (https://arduinojson.org / https://github.com/bblanchon/ArduinoJson) antes de compilar o código? Além disso, se tiver digitado o código na IDE, verifique os nomes das funções.

Sim, instalei conforme foi instruído no vídeo acima. E sobre a digitação, eu copiei e colei o código apenas substituindo pelas informações como nome do wifi e etc. . Já conferi letra por letra e esta função está exatamente igual a escrita aqui. :<