IoT DevKit - 5. Leitura de Temperatura e Umidade

Descrição

Neste experimento entendemos como o sensor DHT11, de temperatura e umidade do ar, funciona. Utilizamos pela primeira vez uma biblioteca na programação. As bibliotecas servem para nos poupar tempo e código já que elas possuem diversas rotinas implementadas que facilitam a vida do programador. Inicialmente entendemos como funciona a leitura do sensor DHT11 e então incrementamos o código fazendo também a leitura do sensor de luminosidade LDR cada vez que o botão é pressionado. Tudo isso é feito, pois no final desta série de tutoriais iremos enviar informações para um servidor que as armazenará. Este envio poderá ser feito por diversas formas, dentre elas via LoRaWAN, uma das tecnologias de comunicação mais promissoras para Internet das Coisas.

Lista de Materiais

Lista completa de produtos

comprar

IoT DevKit - LoRaWAN

R$299.90

Código

/************************************************
* RoboCore - IoT DevKit - LoRaWAN   
*
* Aprendendo a utilizar o sensor de temperatura e
* umidade do kit, em conjunto com o sensor de 
* luminosidade e botao.
***********************************************/

//Inclusao da bilbioteca do sensor DHT11 
#include "DHT.h"

//Declaracao das variaveis dos pinos dos sensores e botao
const int pinoDHT = 12;
const int pinoBotao = 4;
const int pinoLDR = 15;

//Declaracao das variaveis que receberao a leitura do botao e sensor de luz
int estadoBotao = 0;
int valorLDR = 0;

//Criacao da instancia DHT, em funcao do pino do sensor e do tipo do DHT
DHT dht(pinoDHT, DHT11);

void setup() {
  //Abrimos uma comunicacao serial para imprimir dados no Monitor Serial
  Serial.begin(115200);
  
  //Inicializamos nosso sensor DHT11
  dht.begin();
      
  //Informamos que o pino do botao atuara como entrada
  pinMode(pinoBotao, INPUT);
}

void loop() {

  //Assimilamos a variavel estadoBotao a leitura digital do pino do botao    
  estadoBotao = digitalRead(pinoBotao);

  //Se o botao estiver pressionado, entramos nesta rotina condicional
  if (estadoBotao == LOW) {
    delay(30);
    estadoBotao = digitalRead(pinoBotao);
	
   	//Criamos duas variaveis locais para armazenar a temperatura e a umidade lidas
    float temperatura = dht.readTemperature();
    float umidade = dht.readHumidity();
	
    //Mostramos no Monitor Serial os valores de temperatura e umidade
    Serial.print("Temperatura: ");
    Serial.print(temperatura);
    Serial.print(" *C - Umidade: ");
    Serial.print(umidade);
    Serial.print(" % - Luminosidade: ");
	
    //Lemos entao o sensor LDR e mapeamos seu valor de 0 a 100 %
    valorLDR = analogRead(pinoLDR);
    valorLDR = map(valorLDR, 4095, 2500, 0, 100);
	
    //Finalizamos a linha impressa no Monitor Serial com a luminosidade em % 
    Serial.print(valorLDR);
    Serial.println(" %");

    while (digitalRead(pinoBotao) == LOW) {
      //Esperamos soltar o botao para nao haver duas leituras
    }
  }
}

Boa tarde pessoal neste projeto IoT DevKit - 5. Leitura de Temperatura e Umidade, deparo sempre com um erro na compilação. In file included from C:\Users\CLEDSON\Documents\Arduino\libraries\DHT_sensor_library\DHT_U.cpp:15:0: C:\Users\CLEDSON\Documents\Arduino\libraries\DHT_sensor_library\DHT_U.h:36:29: fatal error: Adafruit_Sensor.h: No such file or directory compilation terminated. exit status 1 Erro compilando para a placa ESP32 Dev Module Parece que não utilizei a biblioteca correta para o DHT11

Erros de compilação geralmente estão atrelados à um problema no código, portanto certifique-se de ter copiado o código completo para a Arduino IDE. Se continuar com o mesmo problema, encaminhe um e-mail para suporte@robocore.net com uma cópia completa da mensagem de erro retornada (basta pressionar o botão "Copiar Mensagem de Erro" e então colá-la no corpo do e-mail).

O monitor serial deve estar configurado com a função "Ambos NL & RC" e com a velocidade de 115200 bps, para que as mensagens do código sejam exibidas, portanto verifique a configuração do seu monitor serial. Se continuar com dificuldades, encaminhe um e-mail para suporte@robocore.net, com o número do seu pedido, algumas fotos do Kit recebido, e algumas capturas de tela do monitor serial.