Comunicação entre Arduinos: UART

Em algumas situações é interessante configurar dois Arduinos para trocar informações entre si. Neste tutorial, iremos programar duas placas para se comunicarem entre si via protocolo serial UART na configuração Master emissor/Slave receptor. Utilizaremos a bliblioteca SoftwareSerial para realizar esta tarefa, mas a mesma também pode ser feita através da Serial em hardware.
Nesse exemplo, ao pressionar o botão conectado à placa Master, o estado do led conectado à placa Slave será alterado.
O protocolo serial assíncrono UART utiliza de dois fios (RX - Receptor e TX - Transmissor) para realizar uma comunicação full duplex ponto-a-ponto permitindo que ambos os Arduinos possam enviar e receber dados ao mesmo tempo. Para que a comunicação ocorra corretamente o baud rate (taxa de transmissão) de ambos os dispositivos deve ser o mesmo.

Para isso precisaremos de:

Confira na imagem ao lado como realizar as conexões de cada BlackBoard.

Agora que você já montou todo o circuito, é necessário programar cada placa com seu código. Neste momento, é importante que você verifique se está gravando a BlackBoard correta, por isso recomendamos que conecte e programe uma placa por vez. Desta forma você não irá se confundir com as portas COM.

Código para a BlackBoard Master (conectada ao botão):

/*                                                                       
      RoboCore - Tutorial Comunicacao entre Arduinos: UART (Master)      
                                                      (03/05/2015)

  Escrito por Marcelo Farias.
 
  Exemplo de como comunicar Arduinos utilizando o protocolo UART.
  
  Altera o estado do LED conectado a placa Slave quando o botao ligado 
  a placa Master for pressionado.
  
  Na placa Master foi utilizado um botao conectado ao pino 4, com o 
  resistor de pullup interno da placa acionado e realizou-se um debounce
  em software. Na placa Slave foi utilizado um LED conectado ao pino 7.
  
  Optou-se por usar um software serial para nao conflitar com a serial
  em hardware no momento da gravacao do codigo, contudo, nada impede de
  utilizar a serial em hardware para este mesmo propósito.
  
  Referencias:
  Exemplo Debounce - https://www.arduino.cc/en/Tutorial/Debounce

*/

#include "SoftwareSerial.h" // Inclui a biblioteca SoftwareSerial

#define buttonPin 4 // número do pino onde o botao esta conectado

// Cria uma serial em software 
SoftwareSerial blackBoardSlave(2,3); // (RX, TX)

boolean buttonState;             // estado atual do botao
boolean lastButtonState = LOW;   // valor da ultima leitura do botao
boolean ledState = HIGH;         // estado atual do LED

// as variaveis a seguir sao do tipo long por conta que o tempo, medido 
// em milessegundos alcancara rapidamente um numero grande demais para 
// armazenar em uma variavel do tipo int
unsigned long lastDebounceTime = 0;  // tempo da ultima modificacao do estado do LED

// tempo de debounce; aumentar se o LED oscilar; espera-se que o LED acenda
// apenas se o botao for pressionado por mais de 50ms
unsigned long debounceDelay = 50;    

void setup() {
  // inicia a serial em software com uma taxa de 9600 bit/s
  blackBoardSlave.begin(9600);

  // configura o pino do botao como entrada com resistor de pullup interno
  pinMode(buttonPin, INPUT_PULLUP);
}

void loop() {
  // le o estado do botao e salva em uma variavel local
  int reading = digitalRead(buttonPin);

  // verifica se voce apenas apertou o botao (i.e. se a entrada foi de LOW 
  // to HIGH), e se ja esperou tempo suficiente para ignorar qualquer ruido

  // se a entrada foi alterada devido ao ruido ou botao ter sido pressionado:
  if (reading != lastButtonState) {
    // reseta o tempo do debounce
    lastDebounceTime = millis();
  }
  
  if ((millis() - lastDebounceTime) > debounceDelay) {
    // qualquer que seja a leitura atual, ela se manteve por um tempo maior
    // que o nosso debounce delay, então atualizemos o estado atual:

    // se o estado do botao foi alterado:
    if (reading != buttonState) {
      buttonState = reading;

      // apenas altera o estado do LED se o novo estado do botao e HIGH
      if (buttonState == HIGH) {
        ledState = !ledState;
  		blackBoardSlave.print(ledState); // envia
      }
    }
  }
  // salva a leitura. No proximo laco este sera o ultimo 
  // estado do botao (lastButtonState)
  lastButtonState = reading;
}

Código para a BlackBoard Slave (conectada ao LED):

/*                                                                       
      RoboCore - Tutorial Comunicacao entre Arduinos: UART (Slave)      
                                                      (03/05/2015)

  Escrito por Marcelo Farias.
 
  Exemplo de como comunicar Arduinos utilizando o protocolo UART.
  
  Altera o estado do LED conectado a placa Slave quando o botao ligado 
  a placa Master for pressionado.
  
  Na placa Master foi utilizado um botao conectado ao pino 4, com o 
  resistor de pullup interno da placa acionado e realizou-se um debounce
  em software. Na placa Slave foi utilizado um LED conectado ao pino 7.
  
  Optou-se por usar um software serial para nao conflitar com a serial
  em hardware no momento da gravacao do codigo, contudo, nada impede de
  utilizar a serial em hardware para este mesmo propósito.
  
  Referencias:
  Exemplo Debounce - https://www.arduino.cc/en/Tutorial/Debounce

*/

#include "SoftwareSerial.h" // Inclui a biblioteca SoftwareSerial

#define ledPin 7 // numero do pino onde o LED esta conectado

// Cria uma serial em software 
SoftwareSerial blackBoardMaster(2,3); // (RX, TX)

void setup() {
  // inicia a serial em software com uma taxa de 9600 bit/s
  blackBoardMaster.begin(9600);
  
  pinMode(ledPin, OUTPUT);  // configura o pino do LED como saida
}

void loop() {
  // verifica se existem dados para serem lidos na serial
  if (blackBoardMaster.available() > 0){
    // le o byte recebido
    char received = blackBoardMaster.read();

    // se o byte recebido corresponde ao caractere '0'(48) apaga o LED
    if (received == '0'){
      digitalWrite(ledPin, LOW);
    }
    
    // se o byte recebido corresponde ao caractere '1'(49) acende o LED
    if (received == '1'){
      digitalWrite(ledPin,HIGH);
    }
  }
}

Agora basta alimentar ambas as placas que tudo deve funcionar perfeitamente. Aperte o botão da BlackBoard Master e o LED conectado a placa Slave deve acender. Se você apertar novamente o mesmo deve apagar.

Comentários

Para fazer comentários é necessário estar logado. Efetuar login.

Você ainda nao é cadastrado? Cadastre-se agora!

bianca22arq
date

Enviado 2021-03-22 20:22:48

// UART (Master) - Botão //

int botao;
boolean statusBotao;


void setup() {
  
  Serial.begin(9600);

  pinMode(botao, INPUT);
  
}

void loop() {

  botao = digitalRead(8);
  if(botao == 1){
    delay(1000);
    statusBotao =! statusBotao;
    Serial.write(statusBotao);
  }
}
// (Slave) - LED //

int led = 12;

void setup() {
  
  Serial.begin (9600);

  pinMode(led, OUTPUT);

}

void loop() {
  if(Serial.available()>0){
    int recebido = Serial.read();

    if(recebido == 0){
      digitalWrite(led,LOW);     
    }

    if(recebido == 1){
      digitalWrite(led,HIGH);
    }
  }
}

bianca22arq
date

Enviado 2021-03-22 20:25:35
bianca22arq

Aqui está a maneira ao qual eu programei, mas funcionou e agora não funciona mais, não sei por qual motivo, poderia me ajudar?
Carreguei o código de maneira separada para os dois arduinos, fiz a ligação no protoborard e funcionou sexta feira, hoje segundo feira fui ligar para inserir mais leds e o led ficou piscando sozinho, o botão já não respeitava mais os comandos

Giovanni5

Enviado 2021-03-23 07:55:03
bianca22arq

Se o projeto deixou de funcionar entre um dia e outro, é sinal que algum ponto não está exatamente como foi testado inicialmente. O código compartilhado parece estar correto, então o problema pode estar no circuito. Verifique se as conexões dos pinos RX e TX não estão invertidas, e certifique-se que o GND de ambas as placas estão interligados.

bianca22arq
date

Enviado 2021-03-19 19:11:36

Boa noite, estou tentando fazer a comunicação de forma serial em hardware, com os cabos Tx e Rx, como sou iniciante tentei ir modificando o código ilustrado, sem usar a biblioteca software serial, a função, int em vez do char, millis e time, mas não funcionou! Vocês poderiam me ajudar a entender como deveria ser a programação onde troco informações e recebo via serial em hardware, um led em um arduino e um botão em outro arduino.

Giovanni5

Enviado 2021-03-22 08:09:48
bianca22arq

O código foi carregado corretamente para as placas, ou a IDE retornou algum erro durante a compilação? A lógica utilizada nas condições "if" do código foram criadas para trabalhar com os valores recebidos em "char", então se você está atribuindo os valores recebidos à uma variável "int", será necessário modificar a lógica das condições considerando a tabela ASCII (https://pt.wikipedia.org/wiki/ASCII).

Giovanni5

Enviado 2021-03-22 08:11:41
bianca22arq

Talvez seja uma boa ideia você adicionar alguma indicação visual que a comunicação entre as duas placas está ativa (acionado o "LED_BUITIN", por exemplo), já que não é possível acompanhar a execução do código pelo monitor serial com a comunicação via Hardware de duas placas UNO.

bianca22arq
date

Enviado 2021-03-24 21:16:13
bianca22arq

Consegui fazer funcionar, era problema físico mesmo! O senhor conseguiria me auxiliar na programação agora inserindo dois LEDs e dois botões, como o programa deve se comportar sua logica.

Giovanni5

Enviado 2021-03-25 08:51:52
bianca22arq

Como você já conseguiu fazer o projeto funcionar usando apenas um botão e um LED, basta replicar a lógica já existente, para o segundo conjunto. Apenas leve em consideração que você terá que identificar as mensagens que são enviadas e recebidas, para acender o LED correto e de acordo com o botão pressionado. Como você está usando uma variável inteira, talvez seja uma boa ideia usar números para fazer essa identificação. Vale lembrar que, infelizmente não trabalhamos com o desenvolvimento de projetos, portanto não temos como lhe ajudar muito além destes direcionamentos.

valter74
date

Enviado 2020-11-20 18:50:41

olá, estou desenvolvendo um projeto, e gostaria de implementar mais componentes, mas me faltam entradas.
gostaria de saber se posso distribuir metade dos componentes em cada arduino.
Estou utilizando o tinkercad para testar antes de fazer a montagem fisica.
obrigado

Giovanni5

Enviado 2020-11-23 08:17:39
valter74

Sim, esta distribuição de portas entre placas que se comunicam serialmente é uma opção para solucionar esse problema, mas, dependendo da aplicação, pode ser um pouco complicado implementar isso. Se você está usando uma placa Arduino com poucas entradas, como uma UNO, você pode substituí-la por uma placa com mais portas, como uma placa da plataforma Arduino Mega (https://www.robocore.net/placa-arduino/blackboard-mega - por exemplo), o que deve facilitar muito a solução deste problema.

parcell
date

Enviado 2020-11-13 20:06:08

Olá, sou iniciante e gostaria de tentar esclarecer uma duvida; Tenho dois arduinos em um projeto (cada um executando algumas tarefas) e um deles está conectado a um Display Nextion, funcionando normalmente.  Eu consigo enviar do outro arduino (via serial) dados para o mesmo Display Nextion?

Francois

Enviado 2020-11-16 12:50:49
parcell

Não trabalhamos com esse tipo de display, mas supomos que não. Provavelmente ele aceita o controle apenas por uma porta, então só um microcontrolador deve enviar as informações para ele. O que você pode fazer então é enviar as informações usando esse Arduino como intermediário ou fazer um chaveamento da comunicação entre os Arduinos, porém essa segunda opção não é muito indicada porque é mais fácil de se perder no controle do display.

mateusuzuelli
date

Enviado 2020-09-10 09:47:34

Bom dia!

Como não possuo 2 arduinos, estou tentando fazer pelo software Thinkercad. Porém a programação não apresenta erro mas não acontece nada.
O que pode estar errado?

Giovanni5

Enviado 2020-09-10 10:38:14
mateusuzuelli

Talvez o circuito esteja com uma inversão na conexão dos pinos das placas, portanto tente inverter essas conexões, e observe o resultado.

nunocastemmel1
date

Enviado 2020-05-12 08:15:45

Olá,
É possível fazer essa ligação, mas usar um sensor IR no master e acender vários leds no slave?
Obrigado.

Giovanni5

Enviado 2020-05-12 09:47:40
nunocastemmel1

Sim, é possível, basta alterar os códigos do master e do slave desta página, para que eles executem o que você deseja.

wallace13
date

Enviado 2019-11-17 19:45:38

Olá,
Estou montando um projeto onde recebo os dados externos através de um atmega328, envio para um atmega328 responsável por  enviar os dados lidos para um banco de dados na web via ESP01.
O problema está no fato de que, para configurar o ESP01, preciso utilizar uma "porta serial" criada pelo softwareserial.h e preciso dela também para essa outra conexão. Se eu startar a Serial1 e depois startar a Serial2, a Serial1 não funciona(nesse caso, não lê os dados recebidos do outro atmega) e se startar a Serial2 e depois startar a Serial1, a comunicação com o ESP01 dá timeout.

wallace13

Enviado 2019-11-17 19:47:54
wallace13

A pergunta é: dá para utilizar mais de uma porta advinda da softwareserial.h ou essa é uma limitação do uno que não dá para contornar? Se sim, é possível criar uma Serial3 também? Precisava dessas portas para fazer meu projeto rodar.

Atenciosamente,
Wallace Rocha

wallace13

Enviado 2019-11-17 21:38:08
wallace13

Consegui resolver o problema dando uma lida na documentação da biblioteca. Para quem enfrentar o mesmo problema e se ver na necessidade de utilizar mais de uma conexão serial, segue a resposta:
O Arduino UNO não consegue ouvir mais de uma conexão serial ao mesmo tempo, portanto, você deve especificar qual porta você quer ouvir. Antes de utilizar uma conexão serial, você deve especificar qual serial você quer ouvir através do comando listen().
Um exemplo:
(...)
  Serial1.listen();
  if (Serial1.available() > 0){
    String param = leitordedados();
    Serial.println(param);
    Serial2.listen()

Francois

Enviado 2019-11-19 12:23:08
wallace13

Exatamente, a biblioteca de serial de software permite apenas uma porta por vez esperando os pacotes. Isso pode ser um inconveniente em alguns projetos, então você pode optar por usar outros microcontroladores com mais portas seriais de hardware (ex: BlackBoard Mega).

guilhermeapk
date

Enviado 2018-04-17 21:27:10

Eu consigo enviar e ler um número inteiro ou uma string ao invés de apenas enviar e ler um cahr?

hallszombie
date

Enviado 2018-04-18 08:31:59
guilhermeapk

A uart vai enviar caracteres, mas você consegue trabalhar com inteiros e string, um exemplo simples de inteiro usando os códigos acima, é usar "int received", se você usar esta variável dessa forma o Arduino já faz a conversão do char que chega, para um inteiro com base na tabela ASCII, agora no caso das string, você deverá compor os caracteres para obter as strings. Ou seja, você apenas envia e recebe caracteres, e cabe ao desenvolvedor fazer a conversão da informação recebida para a informação desejada.

Dreadd
date

Enviado 2017-10-18 13:50:29

Ola, estou com uma dificuldade, como faço para acionar outras saídas (leds)  por botões diferentes, do master para slave, na parte do SoftwareSerial blackBoardSlave(2,3); deixaria o mesmo para todos, com a mesma taxa de bits? ou adiciona um novo SoftwareSerial e com bits diferentes?
Pois, fiz como me disseram, mas ele aciona uma saída ou todos, tentei adicionar mais seriais, mas acho que não esteja correto. Gostaria de saber o que seria necessário adicionar. Agradecido pela atenção.

Francois

Enviado 2017-10-18 15:32:48
Dreadd

Você não precisa declarar outra variável de serial, pois você continuará usando os mesmos pinos para a comunicação. Você precisa diferenciar os comandos enviados para cada botão, pois o código do tutorial envia sempre 0 ou 1. Você pode modificar o código para enviar (A) e (a) para o botão/LED 1, (B) e (b) para o botão/LED 2, e assim por diante. Isso significa que será necessário fazer uma verificação do estado atual (ledState) de cada par botão + LED, para em seguida enviar o caractere correspondente.

Dreadd
date

Enviado 2017-10-08 19:27:37

Ola, estou com uma dificuldade, como faço para acionar outras saídas (leds)  por botões diferentes, do master para slave,

MarceloFarias
date

Enviado 2017-10-09 10:41:49
Dreadd

Tente entender como o código funciona e perceberá que basta multiplicar algumas linhas de código já existentes para declarar, configurar e ler mais botões e enviar essa informação via serial. No slave da mesma maneira, declarar e configurar mais leds para que você possa acioná-los de acordo com os caracteres recebidos. Você precisará utilizar caracteres diferentes também, por exemplo, &#39;2&#39; para acender e &#39;3&#39; para apagar.